home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Apple II Magazines (DO)
/
Micro on the Apple Volume 2 (1981)(Micro Ink).zip
/
Micro on the Apple Volume 2 (1981)(Micro Ink).do
/
MATRIX DEMO.bas
< prev
next >
Wrap
BASIC Source File
|
1996-12-24
|
2KB
|
51 lines
1 REM ************************
2 REM * *
3 REM * MATRICES & APPLESOFT *
4 REM * BY C. BONGERS *
5 REM * *
6 REM * MATRIX DEMO *
7 REM * *
8 REM * COPYRIGHT (C) 1981 *
9 REM * MICRO INK, INC. *
10 REM * CHELMSFORD, MA 01824 *
11 REM * ALL RIGHTS RESERVED *
12 REM * *
13 REM ************************
14 REM
15 REM THE LINEAR MODEL
16 REM
18 HOME
20 INPUT "NUMBER OF OBSERVATIONS ? ";N
30 INPUT "NUMBER OF INDEPENDENT VARIABLES ? ";M:M1 = M +1
40 IF M1 > = N THEN PRINT : PRINT "TOO FEW OBSERVATIONS ": STOP
50 DIM X(N,M1),XA(M1,N),Y(N,1),B(M1,1),E(N,1),EA(1,N),S(M1,M1)
60 DIM V1(1,1),V2(1,1),H(M1,1),J(1,N)
70 PRINT : PRINT "INPUT THE ELEMENTS OF THE Y-VECTOR": PRINT
80 FOR I = 1 TO N
90 PRINT "ELEMENT ";I;" ? ";: INPUT "";Y(I,1):X(I,1) = 1
100 NEXT I
110 FOR J = 2 TO M1
120 PRINT : PRINT "INPUT THE ELEMENTS OF THE X";J -1;"-VECTOR": PRINT
130 FOR I = 1 TO N
140 PRINT "ELEMENT ";I;" ? ";: INPUT "";X(I,J)
150 NEXT I,J
160 REM CALCULATE RESULTS
170 & XA = TRN(X):S = XA.X:S = NEINV(S):H = XA.Y:B = S.H
180 IF S(0,0) = 0 THEN PRINT "THE S-MATRIX IS SINGULAR": STOP
190 PRINT : PRINT "THE LEAST SQUARES EQUATION EQUALS ": PRINT
200 PRINT "Y = ";B(1,1);
210 FOR J = 2 TO M1: IF B(J,1) > = 0 THEN PRINT "+";
220 PRINT B(J,1);"*X";J -1;
230 NEXT : PRINT : PRINT
240 & E = X.B:EA = TRN(E):E = Y -E
250 PRINT "** THE TABLE OF RESIDUALS **": PRINT
260 PRINT "NO"; TAB( 4);"OBSERVED Y"; TAB( 16);"ESTIMATED Y"; TAB( 29);"RESIDUAL"
270 FOR I = 1 TO N
280 PRINT I; TAB( 4);Y(I,1); TAB( 16);EA(1,I); TAB( 29);E(I,1)
290 NEXT I: PRINT
300 & EA = TRN(E):V1 = EA.E
310 PRINT "STANDARD DEV. RESIDUALS: "; SQR(V1(1,1)/(N -M1))
320 & J = (1):V2 = J.Y:V2 = V2/(N):E = Y -(V2(1,1)):EA = TRN(E):V2 = EA.E
330 R = (V2(1,1) -V1(1,1))/V2(1,1): IF R <0 THEN R = 0
340 PRINT "R^2";: HTAB (24): PRINT ": "; SQR(R)
350 END